Risolto File batch per rinominare file

[attila666]

Buongiorno, avrei necessità di togliere a decine di file dentro la stessa cartella il suffisso "L_" dall'inizio del nome ad esempio da " L_file1.xlsx" a "file1.xlsx" tramite un file bach, magari selezionando anche il percorso, pensavo di trovare rapidamente su google come fare ma non riesco a farlo funzionare, questo codice si avvicina a quanto mi occorre ?

ren ??? - L_???.xlsx ???.xlsx

 

[Powerwin]

Ciao, prova questo codice in un file .bat e fammi sapere

@echo off
setlocal EnableDelayedExpansion

REM Chiedi all'utente di selezionare la cartella
set "folderPath="
for /f "delims=" %%I in ('powershell -Command "(New-Object -ComObject Shell.Application).BrowseForFolder(0, 'Seleziona la cartella da modificare', 0, 0).Self.Path"') do set "folderPath=%%I"

REM Esci se l'utente ha premuto Annulla
if not defined folderPath exit /b

REM Cicla attraverso tutti i file nella cartella
for %%F in ("%folderPath%\*.*") do (
    set "fileName=%%~nF"
    set "fileExtension=%%~xF"

    REM Rimuovi i primi 2 caratteri "L_"
    set "newFileName=!fileName:~2!!fileExtension!"

    REM Rinomina il file
    ren "%%F" "!newFileName!"
)

echo Rimozione completata!

 

[attila666]

@Powerwin Funziona, anche troppo ogni volta che la lancio si mangia i primi caratteri del file, anche se non hanno la "L_" come parte iniziale, scusa forse non avevo specificato che ci sono altri file nella cartella senza il suffisso "L_" e non devono essere toccati

 

[Powerwin]

beh beh, se tu chiedi una cosa noi non possiamo indovinare tutte le altre casistiche che conosci solo tu

 

[attila666]

@Powerwin Ne sono cosciente, per questo mi sono scusato

 

[Powerwin]

Prova quest'altro codice

@echo off
setlocal EnableDelayedExpansion

REM Chiedi all'utente di selezionare la cartella
set "folderPath="
for /f "delims=" %%I in ('powershell -Command "(New-Object -ComObject Shell.Application).BrowseForFolder(0, 'Seleziona la cartella da modificare', 0, 0).Self.Path"') do set "folderPath=%%I"

REM Esci se l'utente ha premuto Annulla
if not defined folderPath exit /b

REM Cicla attraverso tutti i file nella cartella
for %%F in ("%folderPath%\L_*.*") do (
    set "fileName=%%~nF"
    set "fileExtension=%%~xF"

    REM Verifica se il nome del file inizia con "L_"
    if /I "!fileName:~0,2!"=="L_" (
        REM Rimuovi i primi 2 caratteri "L_"
        set "newFileName=!fileName:~2!!fileExtension!"

        REM Rinomina il file
        ren "%%F" "!newFileName!"
    )
)

echo Rimozione completata!

p.s. ho modificato il codice postato poco fa

 

[attila666]

@Powerwin perfetto gentilissimo,
P.s. una chicca, c'e anche modo di impostare il percorso di ricerca iniziale già nella cartella in cui risiede il file ? la corrispondenza di

.InitialFileName = pathActual

in VB ?

 

[Powerwin]

P.s. una chicca, c'e anche modo di impostare il percorso di ricerca iniziale già nella cartella in cui risiede il file ?

Questo almeno lo lascio a te, altrimenti faccio tutto io

 

[attila666]

@Powerwin hai ragione , buona giornata