Risolto Estrazione consumi condizionata dal periodo

[sarawest_81]

Buongiorno a tutti

gentilmente chiedo un aiuto su una estrazione

ho dei punti nella colonna A1 del Foglio 1 dove ho necessità che vengano popolate le colonne D, E,F,G...i dati per queste colonne sono in Foglio2 ma non so che formula applicare perchè ho più variabili , il mese e l'anno

vi ringrazio molto per la pazienza
Sara

 

[Terio]

chiedo un aiuto su una estrazione

Ti chiedo un supporto anch'io: visto che la precedente discussione ha avuto più soluzioni e sembra risolta, ti chiedo di chiuderla per poter proseguire con questa.
Ho, nel frattempo, corretto il titolo riducendo l'inutile maiuscolo,
ciao.

edit
Discussione riaperta e, venendo alla tua richiesta:

ho necessità che vengano popolate le colonne D, E,F,G...i dati per queste colonne sono in Foglio2 ma non so che formula applicare perchè ho più variabili , il mese e l'anno

ti propongo:
D2
=INDICE(Foglio2!$B$2:$G$45;CONFRONTA($A2&$B2;Foglio2!$E$2:$E$45&Foglio2!$F$2:$F$45;0);CONFRONTA(D$1;Foglio2!$B$1:$G$1;0))
probabilmente da confermare matriciale nella 2007 in tuo possesso, usando la combinazione CTRL+SHIFT+ENTER al posto del solo ENTER e poi la puoi trascinare fino a G5 ed oltre.

Ciao.

 

[sarawest_81]

scusa ma questa formula non tiene conto del punto (colonna c foglio1) (colonna A foglio2)

 

[Sgrubak]

Per la tensione in D2 puoi usare
=INDICE(Foglio2!$G$2:$G$45;CONFRONTA(1;(Foglio2!$A$2:$A$45=Foglio1!C2)*(Foglio2!$F$2:$F$45=Foglio1!B2)*(Foglio1!A2=Foglio2!$E$2:$E$45);0))
Adegua la parte in rosso per le altre colonne e confermale tutte CTRL+SHIFT+ENTER, poi trascinale in basso.

 

[Terio]

questa formula non tiene conto del punto (colonna c foglio1) (colonna A foglio2)

Vero, ma basta aggiungerla:
=INDICE(Foglio2!$B$2:$G$45;CONFRONTA($A2&$B2&$C2;Foglio2!$E$2:$E$45&Foglio2!$F$2:$F$45&Foglio2!$A$2:$A$45;0);CONFRONTA(D$1;Foglio2!$B$1:$G$1;0))
se non ne hai capito il funzionamento, ti do le spiegazioni per gestirla.

Ciao.

 

[sarawest_81]

grazie, mi puoi dare spiegazioni? non ho capito il funzionamento

 

[Terio]

mi puoi dare spiegazioni?

Certamente, per cui provo a scomportela:
=INDICE(Foglio2!$B$2:$G$45 la formula recupera dall'intervallo di origine contenuto nel 2° foglio il dato, la cui riga ...
;CONFRONTA( ... la cerca ...
$A2&$B2&$C2 ... combinando i valori in A, B e C ...
;Foglio2!$E$2:$E$45&Foglio2!$F$2:$F$45&Foglio2!$A$2:$A$45 ... nelle colonne E, F e A del Foglio2, questa matrice composta rende necessaria la conferma matriciale
;0) lo zero finale, costringe il CONFRONTA ad un match esatto
;CONFRONTA(D$1;Foglio2!$B$1:$G$1;0)) per recuperare la colonna da cui recuperare il dato, identifica la colonna sempre con un CONFRONTA in orizzontale sulle etichette di campo che (brava ) coincidono

Se serve altro, chiedi nello specifico,
ciao.

 

[sarawest_81]

Grazie sei stato molto gentile...ho capito la formula e l'ho utilizzata
grazie ancora

 

[Terio]

Grazie sei stato molto gentile...ho capito la formula e l'ho utilizzata

Grazie del riscontro, ho solo spostato la coppa sul messaggio che la conteneva, la spiegazione mi fa piacere sia stata apprezzata, ma non costituisce la soluzione.

Ciao.