Risolto Convalida presenza di tutti i valori una volta soltanto

[SAMUELE.1]

Buongiorno,
premetto che utilizzo Google Fogli, avrei la necessità di un riscontro se inserisco tutti i valori della colonna B23 alla B33 (nome di vari frutti) una sola volta al giorno. Mi servirebbe il riscontro sulla riga da B19 a H19.
Per esempio il giorno 02 ho volutamente inserito 2 volte "mele", ma dovrei inserirlo solo una volta per cui vorrei un riscontro negativo. E sul mercoledì 03 ho dimenticato un tipo di frutto per cui anche qui vorrei un riscontro Negativo.
Spero riusciate ad aiutarmi
Vi ringrazio anticipatamente

Samuele

[file rimosso - inserire link al foglio]​

 

[Terio]

utilizzo Google Fogli, avrei la necessità di un riscontro se inserisco tutti i valori della colonna B23 alla B33 (nome di vari frutti) una sola volta al giorno. Mi servirebbe il riscontro sulla riga da B19 a H19

Per verificare la presenza di tutti i nomi puoi usare FILTER per restituirti i mancanti, ma ho dovuto cancellare il file in quanto per quell'applicativo il file Excel non serve: pubblica il link al foglio di esempio.

Ciao.

 

[SAMUELE.1]

Buongiorno Terio,
ti inoltro il link.

prova frutta

docs.google.com

grazie mille

 

[Terio]

ti inoltro il link.

Non consente l'accesso,
ciao.

 

[SAMUELE.1]

Aggiornata la condivisione, porta pazienza... Adesso dovresti vederlo

prova frutta

docs.google.com

 

[Terio]

Solo in B16
=LET(f;B23:B33;BYCOL(B4:H15;LAMBDA(c;FILTER(f;NOT(COUNTIF(c;f))))))
i valori esemplificativi della colonna D mi sembrano errati,
ciao.
edit
Meglio:
=LET(f;B23:B33;BYCOL(B4:H15;LAMBDA(c;IFNA(FILTER(f;NOT(COUNTIF(c;f)))))))
consente anche di contare le occorrenze in caso siano tutti presenti
B19
=ARRAYFORMULA(BYCOL(B16:H18;LAMBDA(c;LET(a;OFFSET(c;-12;0;12);IF(OR(COUNTA(c);MAX(COUNTIF(a;a))>1);"NO";"SI")))))

 

[SAMUELE.1]

Grazie Terio, ho aggiornato la tua formula considerando anche le righe "assenze". Funziona, mi restituisce i nomi non inseriti altrimenti mi restituisce un errore.
Occorre un altra formula per segnare se in quella colonna C4:C18 ci sono dei doppioni (in questo caso mele)?

 

[Terio]

Occorre un altra formula per segnare se in quella colonna C4:C18 ci sono dei doppioni (in questo caso mele)?

Le hai applicate male:

Solo in B16
=LET(f;B23:B33;BYCOL(B4:H15;LAMBDA(c;FILTER(f;NOT(COUNTIF(c;f))))))
...
B19
=ARRAYFORMULA(BYCOL(B16:H18;LAMBDA(c;LET(a;OFFSET(c;-12;0;12);IF(OR(COUNTA(c);MAX(COUNTIF(a;a))>1);"NO";"SI")))))

Ti ho evidenziato in quali celle andavano inserite,
ciao.

 

[SAMUELE.1]

ottimo, sono riuscito ad applicare il tutto!!!!
Grazie mille.
Sempre perfetto

 

[Terio]

Grazie

Grazie a te dei riscontri,
ciao.